Unit BUX;
Interface
Uses Dos;

Type
  TReszvenySorszam = LongInt;
  TReszvenyNev = String[30];
  TNapSzam = 1..999;

  TReszveny = Record
		Sorszam : TReszvenySorszam;
		Nev : TReszvenyNev;
	     End;

  TForgalmiAdat = Record
		   Sorszam : TReszvenySorszam;
		   kezdo, zaro, min, max, atlag : Word;
		 End;


Function ReszvenyNyit : boolean;
			{megnyitja a RESZVENY.TXT-t olvas shoz}
Function MiANevedAranyom (hanyadik : TReszvenySorszam) : TReszvenyNev;
	{r‚szv‚ny sz ma alapj n kikeresi a r‚szv‚ny nev‚t a RESZVENY.TXT-b‹l}
Procedure ReszvenyZar;
			{lez rja a RESZVENY.TXT-t}


Function NapNyit (n : TNapSzam) : boolean;
			{megnyitja az n. napot}
Procedure NapOlvas(hanyadikat : TReszvenySorszam; var kimenet : TForgalmiAdat);
	{kiolvassa a megadott sorsz mŁ r‚szv‚ny aznapi forgalmi adatait}
Procedure NapKovOlvas(var kimenet : TForgalmiAdat);
	{ezzel lehet szekvenci lisan olvasni a f jlt, ha ez esik jobban k‚zre
	  az el‹bbi t”mbszerű (direkt-f jlos stĄlus) helyett}
Function NapVege : boolean;
		{EOF(f), V‚ge?(f), V‚ge-e(f) fggv‚ny, vagy ahogy megszoktad,
		 igaz ‚rt‚ket ad  vissza, ha a file v‚g‚n  lsz ‚s m r nincs
		 t”bb olvasand˘ adat}
Procedure NapZar;
			{lez rja az n. napot}

Implementation

Var
  rtxt, mtxt : text;
  mtxt_szama : integer;
  rtxt_zarva, mtxt_zarva : boolean;
  rtxt_kov_rekord_szama, mtxt_kov_rekord_szama : TReszvenySorszam;

{***************************************************************************}
	{A RESZVENY.TXT-ben matat˘ elj r sok ‚s fggv‚nyek}

Function ReszvenyNyit;
Begin
  if rtxt_zarva then
  Begin
    Assign(rtxt,'RESZVENY.TXT');
    {$I-} Reset(rtxt); {$I+}
    rtxt_kov_rekord_szama:=0;
    rtxt_zarva:=(IOresult<>0);
  End;
  ReszvenyNyit:=not rtxt_zarva;
End;

Function MiANevedAranyom;
Var
  i : TReszvenySorszam;
  s : String;
Begin
  If not ReszvenyNyit then
  Begin
    WriteLn('Bux.Tpu - MiANevedAranyom : HIľNYZIK a RESZVENY.TXT f jl!');
    Halt(1);
  End;

  If hanyadik<rtxt_kov_rekord_szama then
    Begin	{ha m r tŁlhaladtunk a szekvenci lis olvas ssal a rekordon
		 akkor nincs mit tenni: Łjb˘l el kell indulni a f jl elej‚r‹l}
      close(rtxt);
      reset(rtxt);
      rtxt_kov_rekord_szama:=0;
    End;

  For i:=rtxt_kov_rekord_szama to hanyadik-1 do readln(rtxt);
	{teh t a k”v. olvas s m r az ˘hajtott rekordot tartalmazza}

  read(rtxt,i);
  readln(rtxt,s);
  while (s[1]=#32) or (s[1]=#9) do delete(s,1,1);
		{leszedjk az elej‚r‹l a felesleges space-eket}
  MiANevedAranyom:=s;
  rtxt_kov_rekord_szama:=hanyadik+1;
End;

Procedure ReszvenyZar;
Begin
  if not rtxt_zarva then
  Begin
    close(rtxt);
    rtxt_zarva:=true;
  End;
End;

{***************************************************************************}
	{A MUNKA.x-ben turk l˘ r‚szek}

Function NapNyit;
Var
  s : string;
Begin
  if (mtxt_szama<>n) or mtxt_zarva then
  Begin
    str(n,s);
    while length(s)<3 do s:='0'+s;
    assign(mtxt,'MUNKA.'+s);
    {$I-} Reset(mtxt); {$I+}
    mtxt_zarva:=(IOresult<>0);
    mtxt_szama:=n;
    mtxt_kov_rekord_szama:=0;
    NapNyit:=not mtxt_zarva;
  End else NapNyit:=true;
End;

Procedure NapOlvas;
Var
  i : TReszvenySorszam;
Begin
  If mtxt_zarva then
  Begin
    WriteLn('Bux.Tpu - NapOlvas : Nincs megnyitott MUNKA.xxx f jl!');
    Halt(1);
  End;
  If hanyadikat<mtxt_kov_rekord_szama then
  Begin
    close(mtxt);
    reset(mtxt);
    mtxt_kov_rekord_szama:=0;
  End;
  For i:=mtxt_kov_rekord_szama to hanyadikat-1 do readln(mtxt);
  read(mtxt,kimenet.sorszam);
  read(mtxt,kimenet.kezdo);
  read(mtxt,kimenet.zaro);
  read(mtxt,kimenet.min);
  read(mtxt,kimenet.max);
  readln(mtxt,kimenet.atlag);
  mtxt_kov_rekord_szama:=hanyadikat+1;
End;

Procedure NapKovOlvas;
Begin
  If mtxt_zarva then
  Begin
    WriteLn('Bux.Tpu - NapKovOlvas : Nincs megnyitott MUNKA.xxx f jl!');
    Halt(1);
  End;
  If mtxt_kov_rekord_szama=0 then
  Begin
    readln(mtxt);
    inc(mtxt_kov_rekord_szama);
  End;
  read(mtxt,kimenet.sorszam);
  read(mtxt,kimenet.kezdo);
  read(mtxt,kimenet.zaro);
  read(mtxt,kimenet.min);
  read(mtxt,kimenet.max);
  readln(mtxt,kimenet.atlag);
  inc(mtxt_kov_rekord_szama);
End;

Function NapVege;
Begin
  NapVege:=EOF(mtxt);
End;

Procedure NapZar;
Begin
  if not mtxt_zarva then
  Begin
    close(mtxt);
    mtxt_zarva:=true;
  End;
End;

{***************************************************************************}
	{A f‹ elj r s, ami a programod el‹tt elindul
	 alapesetben amĄg nem haszn lod egyik fenti elj r st sem, addig
	 nem csin l semmi l‚nyegeset}

BEGIN
  mtxt_szama:=0;
  rtxt_zarva:=true;
  mtxt_zarva:=true;
  rtxt_kov_rekord_szama:=0;
  mtxt_kov_rekord_szama:=0;
END.